#!/usr/bin/env zsh
#
# Author  : Dennis Eriksen <d@ennis.no>
# File    : tmux.zsh
# Created : 2023-11-30
#

# Some tmux history - https://www.undeadly.org/cgi?action=article&sid=20090712190402

#
# Set env and functions
#

# Set dir
TMUXDIR="$XDG_CONFIG_HOME/tmux"

VERSION=$(tmux -V)

if [[ $VERSION =~ '^tmux[^0-9]*([.0-9]+).*' ]]; then
  TMUX_VERSION=${match[1]}
else
  print -u2 -- "Could not parse TMUX-version $VERSION. Setting TMUX_VERSION to 3.3 and hoping for the best."
  TMUX_VERSION="3.3"
fi

# OpenBSD tmux sets version to "tmux openbsd-A.B" (where A.B is the version of
# OpenBSD, NOT tmux), while portable tmux sets "X.Y". This makes it hard to
# compare versions! My solution is to have a table to convert OpenBSD-version
# to portable tmux version. This table contains all OpenBSD-versions, not all
# tmux-versions, because we convert OpenBSD-version to tmux-version. The
# correct tmux-version will be the last release before (or around) the OpenBSD
# release.
if [[ $VERSION == *openbsd* ]]; then
  typeset -A VERSION_TABLE=(
#   obsd tmux  openbsd-   tmux-releasedate
    7.6  3.5 # TBA        2024-09-27
    7.5  3.4 # 2024-04-05 2024-02-13
    7.4  3.3 # 2023-10-16 2022-06-01
    7.3  3.3 # 2023-04-10 2022-06-01
    7.2  3.3 # 2022-10-20 2022-06-01
    7.1  3.2 # 2022-04-21 2021-03-13
    7.0  3.2 # 2021-10-14 2021-04-13
    6.9  3.2 # 2021-05-01 2021-04-13
    6.8  3.1 # 2020-10-18 2020-02-04
    6.7  3.1 # 2020-05-19 2020-02-04
    6.6  3.0 # 2019-10-17 2019-06-14
    6.5  2.9 # 2019-04-24 2019-04-24
    6.4  2.8 # 2018-10-18 2018-10-17
    6.3  2.7 # 2018-04-02 2018-03-29
    6.2  2.6 # 2017-10-09 2017-10-05
    6.1  2.4 # 2017-04-11 2017-04-20
    6.0  2.3 # 2016-09-01 2016-09-29
    5.9  2.2 # 2016-03-29 2016-04-11
    5.8  2.1 # 2015-10-18 2015-10-18
    5.7  2.0 # 2015-05-01 2015-03-01
    5.6  1.9 # 2014-11-01 2014-02-20
    5.5  1.9 # 2014-05-01 2014-02-20
    5.4  1.8 # 2013-11-01 2013-03-26
    5.3  1.8 # 2013-05-01 2013-03-26
    5.2  1.7 # 2012-11-01 2012-10-13
    5.1  1.6 # 2012-05-01 2012-01-23
    5.0  1.5 # 2011-11-01 2011-07-09
    4.9  1.4 # 2011-05-01 2010-12-27
    4.8  1.3 # 2010-11-01 2010-07-18
    4.7  1.2 # 2010-05-19 2010-03-10
    4.6  1.0 # 2009-10-18 2009-09-20
    4.5  0.8 # 2009-05-01 2009-04-21
    )
    TMUX_VERSION=$VERSION_TABLE[$TMUX_VERSION]
fi

tmux setenv -g TMUX_VERSION $TMUX_VERSION

# function to execute files only if they exist
execute() { [[ -f $1 && -r $1 ]] && $1 }


#
# Colors & style
#

# https://github.com/tmux/tmux/wiki/FAQ#how-do-i-use-rgb-colour
if (( TMUX_VERSION >= 3.2 )); then
  tmux set -sa terminal-features ',xterm*:RGB'
  #tmux set -sa terminal-features ",alacritty:usstyle"
else
  tmux set -sa terminal-overrides ",xterm*:Tc"
fi

# https://ryantravitz.com/blog/2023-02-18-pull-of-the-undercurl/
if (( TMUX_VERSION >= 3.0 )); then
  # focus events enabled for terminals that support them
  tmux set -g focus-events on

  # Undercurl and underscore with colors
  tmux set -sa terminal-overrides ',*:smuc=\E[4:3m' # https://github.com/tmux/tmux/issues/1492#issuecomment-426299083
  tmux set -sa terminal-overrides ',*:Smulx=\E[4::%p1%dm'  # undercurl support
  tmux set -sa terminal-overrides ',*:Setulc=\E[58::2::%p1%{65536}%/%d::%p1%{256}%/%{255}%&%d::%p1%{255}%&%d%;m'  # underscore colours - needs tmux-3.0
fi

# import theme-stuff
if (( TMUX_VERSION >= 1.9 )); then
  if [[ ${COLORTERM} == "truecolor" ]]; then
    tmux source "$TMUXDIR/themes/tmux-24bit.conf"
  elif (( COLORTERM == 256 )); then
    tmux source "$TMUXDIR/themes/tmux-256color.conf"
  fi
else
  tmux source "$TMUXDIR/themes/tmux-1.8.conf"
fi


#
# Plugins
#

# sensible config
execute "$TMUXDIR/lib/tmux-sensible/sensible.tmux"

# prefix highlight
(( TMUX_VERSION >= 1.9 )) && execute "$TMUXDIR/lib/tmux-prefix-highlight/prefix_highlight.tmux"


#
# Local config
#

[[ -r "$TMUXDIR/tmux.conf.local" ]] && \
  tmux source "$TMUXDIR/tmux.conf.local"

[[ -r "$TMUXDIR/tmux.zsh.local" ]] && \
  zsh "$TMUXDIR/tmux.zsh.local"


# finish on a positive note
exit 0