#!/usr/bin/env zsh
################################################################################
#
# This file is autoloaded by .zshrc, and actually loaded when executed
#
################################################################################

# Forked from VCS_INFO_detect_git in zsh, with some extra help from https://old.reddit.com/r/zsh/comments/10a3h7a/show_git_branch_script/j41x6sv/

setopt localoptions NO_shwordsplit extendedglob

[[ $1 == '--flavours' ]] && { print -l git-p4 git-svn; return 0 }

# The original code forks and executes git for *every* dir, even if not in a
# git-repo. This new code does not.
if (( $+commands[git] )) && [[ -n $GIT_DIR || -n ./(../)#.git(#qN) ]] &&
  vcs_comm[gitdir]="$(${vcs_comm[cmd]} rev-parse --git-dir 2> /dev/null)"; then
  if [[ -d ${vcs_comm[gitdir]}/svn ]]; then
    vcs_comm[overwrite_name]='git-svn'
  elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]]; then
    vcs_comm[overwrite_name]='git-p4'
  fi
  return 0 # detected git-dir
fi

return 1 # no git-dir


# Original code:
#if VCS_INFO_check_com ${vcs_comm[cmd]} && vcs_comm[gitdir]="$(${vcs_comm[cmd]} rev-parse --git-dir 2> /dev/null)" ; then
#    if   [[ -d ${vcs_comm[gitdir]}/svn ]]             ; then vcs_comm[overwrite_name]='git-svn'
#    elif [[ -d ${vcs_comm[gitdir]}/refs/remotes/p4 ]] ; then vcs_comm[overwrite_name]='git-p4' ; fi
#    return 0
#fi
#return 1


# END OF FILE #################################################################