#!/usr/bin/env zsh
################################################################################
#
# This file is autoloaded by .zshrc, and actually loaded when executed
#
################################################################################

emulate -L zsh

_SAY_COLORCODE_s6='%F{159}'
_SAY_COLORCODE_s7='%F{245}'
_SAY_COLORCODE_e6='%f'
_SAY_COLORCODE_e7='%f'
autoload -Uz say

autoload -RUz zrecompile || { say warning "Could not load zrecompile" && return 1 }

local -aU files clean



#
# zdotfiles
#
say debug "Checking dotfiles"

() {
  for f in $@; zrecompile -p -- -R $f | say -i0
  clean+=($@)
} ~/.zshenv $ZDOTDIR/{.zcalcrc,.zlogin,.zlogout,.zprofile,.zshrc,.zshrc.local}(-.N)


#
# zcompdump
#
say debug "Checking $ZCACHEDIR/zcompdump"
# if zcompdump exists and is non-zero
() {
  [[ -s $1 ]] && zrecompile -p -- -M $1 | say -i0
  clean+=($1)
} $ZCACHEDIR/zcompdump



#
# functions and completion files
#
say debug "Checking local functions"
() {
  zrecompile -p -- -M -U ${@[1]:h}.zwc $@ | say -i0
  clean+=(${@[1]:h}.zwc)
} $ZDOTDIR/functions/*(-.N)


#
# completion files
#
say debug "Checking local completion-files"
() {
  (( ARGC )) && zrecompile -p -- -M -U ${@[1]:h}.zwc $@ | say -i0
  clean+=(${@[1]:h}.zwc)
} $ZDATADIR/completion/*(-.N)



#
# Misc functions
#
say debug "Checking misc functions"

local -aU funcs tmpfun vcss files=()
funcs=( colors
        compinit
        edit-command-line
        is-at-least
        promptinit
        run-help
        select-word-style
        vcs_info
        zcalc
        zrecompile
        zmv
        _cp
        _grep
        _journalctl
        _ls
        _mv
        _systemctl
        _vim )

## include vcs_info-functions
funcs+=(${^fpath}/vcs_*(-.N:t) ${^fpath}/VCS_*(-.N:t))
# put all vcs-specific functions in their own array so we can remove the vcss we don't need
tmpfun=(${(M)funcs:#VCS_INFO_detect_*} ${(M)funcs:#VCS_INFO_get_data_*})
# remove the vcs-specific ones from $funcs
funcs=(${funcs:|tmpfun})
# create array with the VCSs that are configured
zstyle -g vcss ':vcs_info:*' enable
# add relevant vcs-functions back to $funcs
for vcs in $vcss; funcs+=(${(M)tmpfun:#*${vcs}})

say debug "misc: funcs=($funcs)"

# Create list of files that the functions belong to
for f in $funcs; do
  for g in ${^fpath}/$f(-.N); files+=( $g ) && break
done

say debug "misc: files=($files)"

zrecompile -p -- -M -U $ZCACHEDIR/misc_functions.zwc $files | say -i0
clean+=($ZCACHEDIR/misc_functions.zwc)



#
# fzf / zsh-autosuggestions / zsh-syntax-highlighting
#
() {
  for f in $@; [[ -r $f && -w ${f:h} ]] && zrecompile -p -- -R $f | say -i0
  clean+=($@)
} $ZDOTDIR/lib/fzf/**/*.zsh(-.N:A) \
  $ZDOTDIR/zsh-autosuggestions/**/*.zsh(-.N:A) \
  $ZDOTDIR/zsh-syntax-highlighting/**/*.zsh(-.N:A)


#
# cleaning
#
say debug "Cleaning old files"
# rm -v is not POSIX, so loop over files to both remove and echo each file
for f in ${^clean%.zwc}.zwc.old(.N); rm -f $f && say debug "removed: $f"
say info Done


# END OF FILE #################################################################