#!/usr/bin/env zsh
emulate -L zsh
################################################################################
#
# This file is autoloaded by .zshrc, and actually loaded when executed
#
################################################################################

local cmd batcmd
# Do not run run-help on well-known aliases
local -a skip
skip=( man )

# get colors in less with man
LESS_TERMCAP_mb=$'\E[01;31m'     # begin blinking
LESS_TERMCAP_md=$'\E[01;31m'     # begin bold
LESS_TERMCAP_me=$'\E[0m'         # end mode
LESS_TERMCAP_se=$'\E[0m'         # end standout-mode
LESS_TERMCAP_so=$'\E[01;44;33m'  # begin standout-mode - info box
LESS_TERMCAP_ue=$'\E[0m'         # end underline
LESS_TERMCAP_us=$'\E[01;32m'     # begin underline

# Only use run-help if it is loaded, there is only one argument, and that argument is not in $skip.
if (( ARGC == 1 && $+functions[run-help] && ! $skip[(I)$1] )); then
  cmd="run-help"
else
  cmd="command man"
fi

if (( $+commands[batcat] )); then
  batcmd=batcat
elif (( $+commands[bat] )); then
  batcmd=bat
fi

# Use bat if $MANPAGER is unset, and we have `bat` and `col`. Unless running run-help on openbsd. Bat will NOT cooperate there.
if (( ! $+MANPAGER && $#batcmd && $+commands[col] )) && [[ ! ( $OSTYPE == openbsd* && $cmd == "run-help" ) ]]; then
  $=cmd $@ | col -b -x | $batcmd --language=man --plain --tabs 4
else
  $=cmd $@
fi


# END OF FILE #################################################################