path: root/prompt_adam3_setup

# adam3 prompt theme

prompt_adam3_help () {
  cat <<'EOF'

This prompt changes the color of your prompt based on the
hostname of your current host. This can be quite nice if you log in to a lot of
different hosts (if you can manage to distribute the prompt, of course).

EOF
}

prompt_adam3_setup () {

  autoload -Uz vcs_info

  # colors
  prompt_adam3_color1=${1:-'multi'}
  prompt_adam3_color2=${2:-'blue'}
  prompt_adam3_color3=${3:-'cyan'}
  prompt_adam3_color4=${4:-'green'}

  # Change color of host, based on hostname
  if [[ $prompt_adam3_color1 == 'multi' ]]; then
    prompt_adam3_hostnamecolor=$(hostname | od | tr ' ' '\n' | awk '{total = total + $1}END{print 1 + (total % 24)}')
    prompt_adam3_hostnamebold=$(hostname | od | tr ' ' '\n' | awk '{total = total + $1}END{print 1 + (total % 2)}')

    # for testing purposes
    #prompt_adam3_hostnamecolor=$(( ( $RANDOM % 24 ) + 1 ))
    #prompt_adam3_hostnamebold=$(( $RANDOM % 2 ))

    # Possible prompt colors
    prompt_adam3_hostnamecolors=(black,red black,green black,yellow black,blue black,magenta black,cyan red,white red,yellow red,cyan green,black green,blue yellow,black yellow,blue blue,white blue,red blue,yellow magenta,white magenta,yellow cyan,white cyan,blue white,black white,red white,blue white,magenta)

    # This is where we set up the actual prompt.
    base_hostname_prompt="%K{${${prompt_adam3_hostnamecolors[$prompt_adam3_hostnamecolor]}%,*}}%F{${${prompt_adam3_hostnamecolors[$prompt_adam3_hostnamecolor]}##*,}}%m%f%k"


    # this will set the hostname in bold in 50% of the time
    if [[ $prompt_adam3_hostnamebold -eq 1 ]]; then base_hostname_prompt="%B$base_hostname_prompt%b"; fi

  else

    # If one wants a specific color, just set ut, plain and simple
    base_hostname_prompt="%K{$prompt_adam3_color1}%m%k"

  fi

  base_prompt="%K{$prompt_adam3_color2}%n@%k$base_hostname_prompt "
  post_prompt="%b%f%k"

  # localoptions allows us to use extendedglob here, and not outside this function.
  setopt localoptions extendedglob
  base_prompt_no_color="${base_prompt//(%K{[^\\\}]#\}|%k)/}"
  post_prompt_no_color="${post_prompt//(%K{[^\\\}]#\}|%k)/}"

  add-zsh-hook precmd prompt_adam3_precmd
}

prompt_adam3_precmd () {
  #setopt noxtrace prompt_subst localoptions
  zstyle ':vcs_info:*' enable git svn
  zstyle ':vcs_info:*' check-for-changes true
  zstyle ':vcs_info:*' check-for-staged-changes true
  zstyle ':vcs_info:*' stagedstr ' S'
  zstyle ':vcs_info:*' unstagedstr ' U'
  zstyle ':vcs_info:*' formats "%F{grey}%s %F{green}%b%F{red}%u%c"
  zstyle ':vcs_info:git*' actionformats "%F{grey}%s %r/%S %F{green}%b%F{red}%u%c %a"
  vcs_info
  local base_prompt_expanded_no_color base_prompt_etc
  local prompt_length space_left promptchar

  base_prompt_expanded_no_color=$(print -P "$base_prompt_no_color")
  base_prompt_etc=$(print -P "$base_prompt%(4~|...|)%3~")
  prompt_length=${#base_prompt_etc}

  # Changing the prompt based on the length of the prompt, should happen based
  # on how long it actually is. The method below will need to be changed.
  if [[ $prompt_length -lt 69 ]]; then
    path_prompt="%B%F{$prompt_adam3_color3}%(4~|...|)%3~%b "
  else
    space_left=$(( $COLUMNS - $#base_prompt_expanded_no_color - 2 ))
    path_prompt="%B%F{$prompt_adam3_color4}%${space_left}<...<%~$prompt_newline%b"
  fi

  # make promptchar bold red if root
  if [[ $EUID == 0 ]]; then promptchar="%F{red}%B%#%b%f"; else promptchar="%F{white}%B%#%b%f"; fi

  PS1="$base_prompt$path_prompt${vcs_info_msg_0_}%{$reset_color%} $promptchar $post_prompt"
  PS2="$base_prompt$path_prompt${vcs_info_msg_0_}%{$reset_color%} %_> $post_prompt"
  PS3="$base_prompt$path_prompt${vcs_info_msg_0_}%{$reset_color%} ?# $post_prompt"
}

prompt_adam3_setup "$@"